Skip to main content

lengthIsMin

Short summary​

This assertion method checks if the current string stringToCheck length is equal or grater than to minLength. Processed strings must be in UTF-8 encoding

Attention: All strings are handled as null-terminated byte streams

Parameters​

NameTypeCommentKind
stringToCheckPOINTER TO BYTEcurrent string to checkinput
minLengthUDINTlower limit of the length of stringToCheckinput
stringLengthUnitUnicodeStringLengthUnitstring length units of measurementinput
messageAssertMessagemessage if the assertion is falseinput

Code​

Declaration​

METHOD lengthIsMin
VAR_INPUT
(* current string to check *)
stringToCheck :POINTER TO BYTE;
(* lower limit of the length of ``stringToCheck`` *)
minLength :UDINT;
(* string length units of measurement *)
stringLengthUnit :UnicodeStringLengthUnit;
(* message if the assertion is false *)
message :AssertMessage;
END_VAR
VAR
(* length of current string to check in bytes *)
stringToCheckByteCount :UDINT;
(* length of current string to check in characters *)
stringToCheckCodePointCount :UDINT;
normalizedStringBuffer :POINTER TO BYTE;
bufferSize :UDINT;
normalizedLength :UDINT;
width :DINT;
visibleCharacters :UDINT := 0;
END_VAR
VAR CONSTANT
(*After decomposition one codepoint can extend up to 4 codepoints*)
NORMALIZATION_FACTOR :UDINT := 4;
END_VAR

Implementation​

CNM_UnicodeUtilities.GetUtf8StringLength(
stringToCheck,
byteCount => stringToCheckByteCount,
characterCount => stringToCheckCodePointCount
);

// check if string is empty
IF (stringToCheckByteCount = 0) THEN
IF (minLength > 0) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF
RETURN;
END_IF

CASE (stringLengthUnit) OF
UnicodeStringLengthUnit.BYTES:
IF (stringToCheckByteCount < minLength) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF

UnicodeStringLengthUnit.CHARACTERS:
IF (stringToCheckCodePointCount < minLength) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF

UnicodeStringLengthUnit.CHARACTERS_NFC:
// string size cant increase with NFC
normalizedStringBuffer := __NEW(BYTE, (stringToCheckByteCount + 1));
IF normalizedStringBuffer = 0 THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('lengthIsMin, malloc failed'));
RETURN;
END_IF
bufferSize := stringToCheckByteCount + 1; // stringsize + NULL terminator

CNM_UnicodeUtilities.NormalizeUtf8String(
utf8StringBuffer := stringToCheck,
normalForm := CNM_UnicodeUtilities.NormalizationForm.NFC,
normalizedStringBuffer := normalizedStringBuffer,
bufferSize := bufferSize,
normalizedStringLength => normalizedLength
);

CNM_UnicodeUtilities.GetUtf8StringLength(
stringAddress := normalizedStringBuffer,
characterCount => stringToCheckCodePointCount
);

__DELETE(normalizedStringBuffer);

IF (stringToCheckCodePointCount < minLength) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF

UnicodeStringLengthUnit.CHARACTERS_NFD:
// string size can increase with NFD
normalizedStringBuffer := __NEW(BYTE, (stringToCheckByteCount * NORMALIZATION_FACTOR + 1));
IF normalizedStringBuffer = 0 THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('lengthIsMin, malloc failed'));
RETURN;
END_IF
bufferSize := stringToCheckByteCount * NORMALIZATION_FACTOR + 1; // stringsize can increase for NFD + NULL terminator

CNM_UnicodeUtilities.NormalizeUtf8String(
utf8StringBuffer := stringToCheck,
normalForm := CNM_UnicodeUtilities.NormalizationForm.NFD,
normalizedStringBuffer := normalizedStringBuffer,
bufferSize := bufferSize,
normalizedStringLength => normalizedLength
);

CNM_UnicodeUtilities.GetUtf8StringLength(
stringAddress := normalizedStringBuffer,
characterCount => stringToCheckCodePointCount
);

__DELETE(normalizedStringBuffer);

IF (stringToCheckCodePointCount < minLength) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF

UnicodeStringLengthUnit.VISIBLE_CHARACTERS:
CNM_UnicodeUtilities.GetUtf8StringWidth(stringToCheck, visibleCharacters => visibleCharacters);
IF (visibleCharacters < minLength)THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('lengthIsMin'));
END_IF

UnicodeStringLengthUnit.WIDTH:
width := CNM_UnicodeUtilities.GetUtf8StringWidth(stringToCheck);
IF ((width < 0) OR_ELSE (TO_UDINT(width) < minLength)) THEN
THIS^.assertionWasWrong(message, THIS^.getDebugInfo('LengthIsMin'));
END_IF
ELSE
; // do nothing
END_CASE