isEqualTo

Short summary

This assertion method checks if the current string stringToCheck is equal to expected. Processed strings must be in Windows-1252 or Windows-1251 encoding

Attention: All strings are handled as null-terminated byte streams

Parameters

Name	Type	Comment	Kind
stringToCheck	POINTER TO BYTE	current string to check	input
expected	POINTER TO BYTE	stringToCheck must be equal to expected	input
ignoreCases	BOOL	TRUE means ignore cases; FALSE means that cases must be equal too	input
message	AssertMessage	message if the assertion is false	input
sbcsType	Tc2_Utilities.E_SBCSType	used Single Byte Character Set (SBCS), is set in Tc2_Utilities.GLOBAL_SBCS_TABLE	input

Code

Declaration

METHOD isEqualTo
VAR_INPUT
	(* current string to check *)
	stringToCheck	:POINTER TO BYTE;
	(* ``stringToCheck`` must be equal to expected *)
	expected		:POINTER TO BYTE;
	(* ``TRUE`` means ignore cases; ``FALSE`` means that cases must be equal too *)
	ignoreCases		:BOOL;
	(* message if the assertion is false *)
	message			:AssertMessage;
	(* used Single Byte Character Set (SBCS), is set in Tc2_Utilities.GLOBAL_SBCS_TABLE *)
	sbcsType 		:Tc2_Utilities.E_SBCSType := Tc2_Utilities.E_SBCSType.eSBCS_WesternEuropean;
END_VAR
VAR
	(* length of current string to check *)
	lengthStringToCheck		:UDINT;
	(* length of ``expected`` *)
	lengthExpectedString	:UDINT;
	(* string address we use to compare, if it's case sensitive it's equal to ``stringToCheck`` *)
	usedStringToCheck		:POINTER TO BYTE;
	(* seacrch string address we use to compare, if it's case sensitive it's equal to ``expected`` *)
	usedExpectedString		:POINTER TO BYTE;
END_VAR
VAR CONSTANT
	(* length of an empty string to avoid Tc2_System.MEMCMP with length 0 *)
	EMPTY_STRING_LENGTH		:UDINT := 0;
END_VAR

Implementation

lengthStringToCheck := THIS^.getStringLength(stringToCheck);
lengthExpectedString := THIS^.getStringLength(expected);

IF lengthStringToCheck <> lengthExpectedString THEN
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('isEqualTo'));
	RETURN;
ELSIF (lengthExpectedString = EMPTY_STRING_LENGTH) THEN
	RETURN;
END_IF

usedStringToCheck := THIS^.getNewUpperCaseString(stringToCheck, lengthStringToCheck, ignoreCases, sbcsType := sbcsType);
usedExpectedString := THIS^.getNewUpperCaseString(expected, lengthExpectedString, ignoreCases, sbcsType := sbcsType);

IF (Tc2_System.MEMCMP(
		usedStringToCheck,
		usedExpectedString, 
		lengthExpectedString
	) <> CNM_ReturnTypes.ComparationResult.EQUAL
) THEN
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('isEqualTo'));
END_IF;

THIS^.freeMemory(usedStringToCheck, ignoreCases);
THIS^.freeMemory(usedExpectedString, ignoreCases);