isEqualTo

Short summary

This assertion method for utf-16 strings checks if the current string stringToCheck is equal to the expected string

Attention: All strings are handled as null terminated word streams. For UTF-16 is end of the string 16#00_00

Parameters

Name	Type	Comment	Kind
stringToCheck	POINTER TO WORD	current string to check	input
expected	POINTER TO WORD	stringToCheck must be equal to expected	input
ignoreCases	BOOL	TRUE means ignore cases; FALSE means cases must be equal too	input
message	AssertMessage	message if the assertion is false	input
normalizeStrings	BOOL	normalize both strings for check	input

Code

Declaration

METHOD isEqualTo
VAR_INPUT
	(* current string to check *)
	stringToCheck	:POINTER TO WORD;
	(* ``stringToCheck`` must be equal to expected *)
	expected		:POINTER TO WORD;
	(* ``TRUE`` means ignore cases; ``FALSE`` means cases must be equal too *)
	ignoreCases		:BOOL;
	(* message if the assertion is false *)
	message			:AssertMessage;
	(*normalize both strings for check*)
	normalizeStrings :BOOL := TRUE;
END_VAR
VAR
	(* length of ``stringToCheck`` in characters *)
	lengthStringToCheck				:UDINT;
	(* length of ``stringToCheck`` in bytes *)
	lengthStringToCheckInByte		:UDINT;
	(* length of ``stringToCheck`` in words *)
	lengthStringToCheckInWord		:UDINT;
	(* length of ``expected`` in characters *)
	lengthExpectedString			:UDINT;
	(* length of ``expected`` in characters *)
	lengthExpectedStringInByte		:UDINT;
	(* length of ``expected`` in characters *)
	lengthExpectedStringInWord		:UDINT;
	(* string address we use to compare, if it's case sensitive it's equal to ``stringToCheck`` *)
	usedStringToCheck				:POINTER TO WORD;
	(* seacrch string address we use to compare, if it's case sensitive it's equal to ``expected`` *)
	usedExpectedString				:POINTER TO WORD;
	
		(* DWORD array we use to check *)
	usedCodePointsToCheck, normalizedUsedCodePointsToCheck :POINTER TO CNM_UnicodeUtilities.UnicodeCodePoint;
	usedCodePointToCheckCount		:UDINT;
	
	(* DWORD array we use to compare *)
	usedExpectedCodePoints, normalizedUsedExpectedCodePoints :POINTER TO CNM_UnicodeUtilities.UnicodeCodePoint;
	usedExpectedCodePointCount		:UDINT;
END_VAR
VAR CONSTANT
	(*After decomposition one codepoint can extend up to 4 codepoints*)
	NORMALIZATION_FACTOR :UDINT := 4;
END_VAR

Implementation

lengthStringToCheckInWord := CNM_UnicodeUtilities.GetUtf16StringLength(stringToCheck);
lengthExpectedStringInWord := CNM_UnicodeUtilities.GetUtf16StringLength(expected);

IF ((lengthStringToCheckInWord <> lengthExpectedStringInWord) AND_THEN NOT normalizeStrings) THEN
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo'));
	RETURN;
END_IF

usedCodePointsToCheck := __NEW(CNM_UnicodeUtilities.UnicodeCodePoint, (lengthStringToCheckInWord+1));
IF (usedCodePointsToCheck = 0) THEN
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo, malloc failed'));
	RETURN;
END_IF
usedExpectedCodePoints := __NEW(CNM_UnicodeUtilities.UnicodeCodePoint, (lengthExpectedStringInWord+1));
IF (usedExpectedCodePoints = 0) THEN
	__DELETE(usedCodePointsToCheck);
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo, malloc failed'));
	RETURN;
END_IF

(* convert ``stringToCheck`` to code points *)
CNM_UnicodeUtilities.GetCodepointsFromUtf16String(
	utf16StringAddress := stringToCheck, 
	utf16StringWordCount := lengthStringToCheckInWord, 
	codepointBuffer := usedCodePointsToCheck,
	bufferSize := SIZEOF(CNM_UnicodeUtilities.UnicodeCodePoint)*(lengthStringToCheckInWord+1), 
	codePointCount => usedCodePointToCheckCount);

(* convert ``searchString`` to code points *)
CNM_UnicodeUtilities.GetCodepointsFromUtf16String(
	utf16StringAddress 	:= expected, 
	utf16StringWordCount := lengthExpectedStringInWord, 
	codepointBuffer	:= usedExpectedCodePoints,
	bufferSize :=  SIZEOF(CNM_UnicodeUtilities.UnicodeCodePoint)*(lengthExpectedStringInWord+1),
	codePointCount => usedExpectedCodePointCount);



IF normalizeStrings THEN
	normalizedUsedCodePointsToCheck := __NEW(CNM_UnicodeUtilities.UnicodeCodePoint, (lengthStringToCheckInWord*NORMALIZATION_FACTOR));
	IF (normalizedUsedCodePointsToCheck = 0) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo, malloc failed'));
		__DELETE(usedCodePointsToCheck);
		__DELETE(usedExpectedCodePoints);
		RETURN;
	END_IF
	normalizedUsedExpectedCodePoints := __NEW(CNM_UnicodeUtilities.UnicodeCodePoint, (lengthExpectedStringInWord*NORMALIZATION_FACTOR));
	IF (normalizedUsedExpectedCodePoints = 0) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo, malloc failed'));
		__DELETE(usedCodePointsToCheck);
		__DELETE(usedExpectedCodePoints);
		__DELETE(normalizedUsedCodePointsToCheck);	
		RETURN;
	END_IF

	CNM_UnicodeUtilities.NormalizeCodepointsFormD(
		codePoints := usedCodePointsToCheck,
		codePointsCount := usedCodePointToCheckCount,
		normalizedCodepoints := normalizedUsedCodePointsToCheck,
		bufferSize := (lengthStringToCheckInWord * NORMALIZATION_FACTOR) * SIZEOF(CNM_UnicodeUtilities.UnicodeCodePoint),
		normalizedCodepointsCount => usedCodePointToCheckCount
	);
	__DELETE(usedCodePointsToCheck);
	usedCodePointsToCheck := normalizedUsedCodePointsToCheck;
	
	CNM_UnicodeUtilities.NormalizeCodepointsFormD(
		codePoints := usedExpectedCodePoints,
		codePointsCount := usedExpectedCodePointCount,
		normalizedCodepoints := normalizedUsedExpectedCodePoints,
		bufferSize := (lengthExpectedStringInWord * NORMALIZATION_FACTOR) * SIZEOF(CNM_UnicodeUtilities.UnicodeCodePoint),
		normalizedCodepointsCount => usedExpectedCodePointCount
	);
	__DELETE(usedExpectedCodePoints);
	usedExpectedCodePoints := normalizedUsedExpectedCodePoints;
	IF (usedCodePointToCheckCount <> usedExpectedCodePointCount) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo'));
		__DELETE(usedCodePointsToCheck);
		__DELETE(usedExpectedCodePoints);
		RETURN;
	END_IF
END_IF

IF (ignoreCases) THEN
	CNM_UnicodeUtilities.GetUpperCaseForCodepoint(usedCodePointsToCheck, usedCodePointToCheckCount);
	CNM_UnicodeUtilities.GetUpperCaseForCodepoint(usedExpectedCodePoints, usedExpectedCodePointCount);
END_IF

IF (Tc2_System.MEMCMP(
		usedCodePointsToCheck,
		usedExpectedCodePoints, 
		usedExpectedCodePointCount*SIZEOF(CNM_UnicodeUtilities.UnicodeCodePoint)
	) <> CNM_ReturnTypes.ComparationResult.EQUAL
) THEN
	THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16IsEqualTo'));
END_IF;

__DELETE(usedCodePointsToCheck);
__DELETE(usedExpectedCodePoints);