lengthIsMax

Short summary

This assertion method checks if the current string stringToCheck is length is equal or less than to maxLength

Attention: All strings are handled as null terminated word streams. For UTF-16 is end of the string 16#00_00

Parameters

Name	Type	Comment	Kind
stringToCheck	POINTER TO WORD	current string to check	input
maxLength	UDINT	upper limit of the length of stringToCheck	input
stringLengthUnit	UnicodeStringLengthUnit	string length units of measurement	input
message	AssertMessage	message if the assertion is false	input

Code

Declaration

METHOD lengthIsMax
VAR_INPUT
	(* current string to check *)
	stringToCheck	:POINTER TO WORD;
	(* upper limit of the length of ``stringToCheck`` *)
	maxLength		:UDINT;
	(* string length units of measurement *)
	stringLengthUnit	:UnicodeStringLengthUnit;
	(* message if the assertion is false *)
	message			:AssertMessage;
END_VAR
VAR
	(* length of ``stringToCheck`` *)
	stringToCheckWordCount, stringToCheckCodePointCount, stringToCheckByteCount	:UDINT;
	normalizedStringBuffer :POINTER TO WORD;
	buffersize, normalizedLength :UDINT;
	width :DINT;
	visibleCharacters :UDINT := 0;
END_VAR
VAR CONSTANT
	(*After decomposition one codepoint can extend up to 4 codepoints*)
	NORMALIZATION_FACTOR :UDINT := 4;
END_VAR

Implementation

CNM_UnicodeUtilities.GetUtf16StringLength(
	stringToCheck,
	wordCount => stringToCheckWordCount,
	characterCount => stringToCheckCodePointCount
);

stringToCheckByteCount := 2 * stringToCheckWordCount;

// check if string is empty
RETURN (stringToCheckWordCount = 0);

CASE (stringLengthUnit) OF
UnicodeStringLengthUnit.BYTES:
	IF (stringToCheckByteCount > maxLength ) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax'));
	END_IF

UnicodeStringLengthUnit.CHARACTERS:
	IF (stringToCheckCodePointCount > maxLength) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax'));
	END_IF	
	
UnicodeStringLengthUnit.CHARACTERS_NFC:
	// string size cant increase with NFC
	normalizedStringBuffer := __NEW(WORD, (stringToCheckWordCount+1));
	IF normalizedStringBuffer = 0 THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax, malloc failed'));
		RETURN;
	END_IF
	buffersize := stringToCheckByteCount+SIZEOF(WORD);
	
	CNM_UnicodeUtilities.NormalizeUtf16String(
		utf16StringBuffer := stringToCheck,
		normalForm := CNM_UnicodeUtilities.NormalizationForm.NFC,
		normalizedStringBuffer := normalizedStringBuffer,
		bufferSize := buffersize,
		normalizedStringLength => normalizedLength
	);
	
	CNM_UnicodeUtilities.GetUtf16StringLength(
		utf16StringAddress := normalizedStringBuffer,
		characterCount => stringToCheckCodePointCount
	);
	
	__DELETE(normalizedStringBuffer);
	
	IF (stringToCheckCodePointCount > maxLength) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax'));
	END_IF
	
UnicodeStringLengthUnit.CHARACTERS_NFD:
	// string size can increase with NFD
	normalizedStringBuffer := __NEW(WORD, ( NORMALIZATION_FACTOR * stringToCheckWordCount + 1));
	IF normalizedStringBuffer = 0 THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax, malloc failed'));
		RETURN;
	END_IF
	// stringsize can increase for NFD + NULL terminator word
	buffersize := stringToCheckByteCount * NORMALIZATION_FACTOR + SIZEOF(WORD); 
	
	CNM_UnicodeUtilities.NormalizeUtf16String(
		utf16StringBuffer := stringToCheck,
		normalForm := CNM_UnicodeUtilities.NormalizationForm.NFD,
		normalizedStringBuffer := normalizedStringBuffer,
		bufferSize := buffersize,
		normalizedStringLength => normalizedLength
	);
	
	CNM_UnicodeUtilities.GetUtf16StringLength(
		utf16StringAddress := normalizedStringBuffer,
		characterCount => stringToCheckCodePointCount
	);
	
	__DELETE(normalizedStringBuffer);
	
	IF (stringToCheckCodePointCount > maxLength) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax'));
	END_IF
	
UnicodeStringLengthUnit.VISIBLE_CHARACTERS:
	CNM_UnicodeUtilities.GetUtf16StringWidth( utf16StringBuffer := stringToCheck, visibleCharacters => visibleCharacters);
	IF ( visibleCharacters > maxLength ) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16lengthIsMax'));
	END_IF
	
UnicodeStringLengthUnit.WIDTH:
	width := CNM_UnicodeUtilities.GetUtf16StringWidth(stringToCheck);
	IF ((width < 0) OR_ELSE (TO_UDINT(width) > maxLength)) THEN
		THIS^.assertionWasWrong(message, THIS^.getDebugInfo('utf16LengthIsMax'));
	END_IF
ELSE
	; // do nothing
END_CASE